PIC18 I2Cモジュール サポートライブラリ

icon 項目のみ表示/展開表示の切り替え

概要

PIC内蔵のI2Cモジュールを使用したI2Cの基本的なプロトコルをサポート スタート・ストップ・リスタート・1byte書き込み・1byte読み込みをサブルーチン化している。
使用する場合はi2c.incをインクルードしi2c.asmをプロジェクトに追加してください
本ライブラリを使用する前にI2Cモジュールの初期化をしてください。
なお、本ライブラリはPIC18F46K22のモジュール1をサポートしている。i2c関連のPIC18F14K50のソースはクロック速度を除きCPU定義のヘッダーファイルの名前をPIC18F46K22に修正しただけでも動作可能であるが本ライブラリはモジュール番号1をレジスタ名に追加している。
I2Cバスの仕様については、次のページに記述がある。
http://www.nxp.com/documents/user_manual/UM10204_JA.pdf

プログラムの説明

ソースファイル

以下のファイルで構成されている
i2c.asm   ・・・ I2Cサポートライブラリ Version 1.00
i2c.inc   ・・・ I2Cサポートライブラリ Version 1.00

サブルーチン

以下のサブルーチンをサポート

i2c_start

スタートコンディションを発行する

i2c_write

WREGの値をI2Cバスへ出力する。

i2c_read

I2Cから1byte入力しWREGに格納する。デバイスへはACKを返す。

i2c_last_read

I2Cから1byte入力しWREGに格納する。デバイスへはNACKを返す。

i2c_stop

ストップコンディションを発行する

ソースコード

i2c.inc

; I2Cサポートライブラリ  Version 1.00
; File:        i2c.inc
; Target:      PIC18F46K22 64Mhz
; アセンブラ:   Microchip MPASM(v5.51)
; 書き込み:     PICKit 3
; リリース:     2014/02/23 09:00

        EXTERN i2c_start,i2c_stop,i2c_restart,i2c_read,i2c_last_read,i2c_write

i2c.asm

; I2Cサポートライブラリ(モジュール1)  Version 1.00
; File:        i2c.asm
; Target:      PIC18F46k22 64Mhz
; アセンブラ:   Microchip MPASM(v5.51)
; 書き込み:     PICKit 3
; リリース:     2014/02/23 09:00

        #INCLUDE <p18f46k22.inc>

        GLOBAL i2c_start,i2c_restart,i2c_stop,i2c_read,i2c_last_read,i2c_write

        CODE

i2c_start   ; i2cにスタートを出力
        bcf     SSP1CON1,WCOL    ;   衝突フラグクリア
        bsf     SSP1CON2,SEN     ;   スタート出力
        btfsc   SSP1CON1,WCOL
        bra     i2c_start       ;   衝突がなくなるまでループ
i2c_start_sen
        btfsc   SSP1CON2,SEN
        bra     i2c_start_sen   ;   SENがクリアされるまでループ
        return

i2c_restart   ; i2cに再スタートを出力
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        bsf     SSP1CON2,RSEN     ;   再スタート出力
i2c_restart_rsen
        btfsc   SSP1CON2,RSEN
        bra     i2c_restart_rsen   ;   RSENがクリアされるまでループ
        return

i2c_read    ;   1byte入力
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        bsf     SSP1CON2,RCEN    ; 受信を許可
i2c_read_sen
        btfsc   SSP1CON2,RCEN
        bra     i2c_read_sen    ; SSPBUFに受信データがセットされるまでループ
        bcf     SSP1CON2,ACKDT   ; ACKを出力
        bsf     SSP1CON2,ACKEN   ; ACKENをセット
i2c_read_sen2
        btfsc   SSP1CON2,ACKEN
        bra     i2c_read_sen2   ; ACKの送信が終了するループ
        movf    SSP1BUF,W
        return

i2c_last_read    ;   最終1byte入力
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        bsf     SSP1CON2,RCEN    ; 受信を許可
i2c_last_read_sen
        btfsc   SSP1CON2,RCEN
        bra     i2c_last_read_sen   ; PICが受信許可状態になるまでループ
        bsf     SSP1CON2,ACKDT   ; NACKを出力
        bsf     SSP1CON2,ACKEN   ; ACKENをセット
i2c_last_read_sen2
        btfsc   SSP1CON2,ACKEN
        bra     i2c_last_read_sen2   ; ACKの送信が終了するループ
        movf    SSP1BUF,W
        return


i2c_write   ; 1byte出力
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        movwf   SSPBUF          ; 書き込みデータをセット
i2c_write_sen
        btfss   PIR1,SSPIF
        bra     i2c_write_sen   ; データ送信完了しACKを受信可能状態になるまで待機

        movlw   0   ;   スレーブからの返信がある場合
        btfss   SSP1CON2,ACKSTAT ; スレーブからACKが返っているかチェック
        movlw   0ffh
        return

i2c_stop    ;   i2cにSTOPを出力
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        bsf     SSP1CON2,PEN     ; ストップ出力
i2c_stop_sen
        btfsc   SSP1CON2,PEN
        bra     i2c_stop_sen     ; 出力が完了するまでループ
        bcf     PIR1,SSPIF      ; 割り込みフラグクリア
        return

        END